Promotic

How to read common XML files in the application

These examples describe how to read specific values or parameters into the PROMOTIC application from XML file using the CreateObject method via Microsoft.XMLDOM.

The example for creating (writing) the XML file is not available here. It is also possible to use the methods over the Microsoft.XMLDOM object, but in most cases it is much easier to create the XML file as a text fule by using the Pm.FileTextWrite method (the whole XML text is first created in a variable of the String type) or Pm.FileTextReplace (the template of the XML file is overwritten with the keywords replaced).

XmlData:

Create the example file named XmlData.xml with these contents

<?xml version="1.0" encoding="utf-8"?>

<pm>

<data>

<item>

<name ID="B">d0</name>

<value>9.381083</value>

</item>

<item>

<name ID="P">d1</name>

<value>20.34651</value>

</item>

<item>

<name ID="K">d2</name>

<value>31.1635</value>

</item>

<item>

<name ID="P">d3</name>

<value>39.94775</value>

</item>

<item>

<name ID="D">d4</name>

<value>48.76433</value>

</item>

</data>

</pm>

Save the XML file, for example, to C:\XmlData.xml. Do not forget to save the file in Unicode UTF-8 format. For example in the Notepad program select "Save as" and change the coding to UTF-8.

Include the following scripts mentioned in examples into the PROMOTIC application. After the application is launched and the script processed the results will be displayed in Debug_info.

The common part of the script:

This is the common part of the script for all examples

VBScriptSelect and copy to clipboard


Dim oXml, b, arrNodes, i, lastNode, oAttr

Set oXml = CreateObject("Microsoft.XMLDOM")
oXml.async = false  'set synchronize load file
b = oXml.load("c:\XmlData.xml")  'connect/load XML file
'Pm.Debug "ActiveX = " & b ' create ActiveX object
'Pm.Debug oXml, true ' displaying the appropriate method
'Pm.Debug oXml.readyState ' view connect state: 0=uninitialized, 1=loading, 2=loaded, 3=interactive, 4=complete
'MsgBox oXml.xml ' view list page

1st Example:

The example reads the field of all tags immersed into the pm/data/item structure of the XML dokument. Then it loops through all tags <item> and pass into the INFO system, using the Debug method, all texts containing tags <name> and <value>

VBScriptSelect and copy to clipboard


Set arrNodes = oXml.selectNodes("//pm/data/item")  'array tags
lastNode = arrNodes.length -1  'total tag count

'write values array "arrNodes"
For i = i To lastNode
  Pm.Debug i & " tag name = " & arrNodes.Item(i).selectSingleNode("name").Text
  Pm.Debug i & " tag value = " & arrNodes.Item(i).selectSingleNode("value").Text
Next

it is also can be used this syntax

VBScriptSelect and copy to clipboard


Set arrNodes = oXml.getElementsByTagName("item")  'array tags
lastNode = arrNodes.length -1  'total tag count

'write values array "arrNodes"
For i = i To lastNode
  Pm.Debug i & " tag name = " & arrNodes.Item(i).childNodes(0).Text
  Pm.Debug i & " tag value = " & arrNodes.Item(i).childNodes(1).Text
Next

2nd Example:

The example reads the field of all tags immersed into the pm/data/item structure of the XML dokument. Then it loops through all tags <name> and pass into the INFO system, using the Debug method, the name and value of the attribute.

VBScriptSelect and copy to clipboard


Set arrNodes = oXml.selectNodes("//pm/data/item/name")  'array tags
lastNode = arrNodes.length -1  'total tag count

'write values array "arrNodes"
For i = i To lastNode
  Set oAttr = arrNodes.Item(i).Attributes.Item(0)  'the oAttr object contains all attributes of the "name" tag
  Pm.Debug oAttr.baseName  'attribute name
  Pm.Debug oAttr.nodeValue  'attribute value
Next

3rd Example:

The example finds first occurrence of the <name> tag in the XML document, having the ID="P" attribute. The text value of the tag is displayed using the Debug method.

VBScriptSelect and copy to clipboard


'value of the first "name" tag having the ID="P" attribute
Dim oNode
Set oNode = oXml.selectSingleNode("//pm/data/item/name[@ID='P']")
Pm.Debug oNode.Text

4th Example:

Uses the Debug method to report ID attribute value of each <name> tag in the XML document.

VBScriptSelect and copy to clipboard


Set arrNodes = oXml.getElementsByTagName("name")
lastNode = arrNodes.length -1

For i = i To lastNode
  Pm.Debug arrNodes.Item(i).getAttribute("ID")
Next

See also:

- Examples of the work with applications excel

- Data sharing by files

- How to save a binary file (image) from url address

- Preconfiguration "Sending the e-mails by the application"

- Example of file transfer by FTP (ActiveX)

PROMOTIC 8.3.30 SCADA system documentation - MICROSYS, spol. s r.o.

Send page remark Contact responsible person

Navigation:

- PROMOTIC SCADA/HMI system

- Documentation content

- Text, file formats

- How to read common XML files in the application

© MICROSYS, spol. s r. o.Tavičská 845/21 703 00 Ostrava-Vítkovice