Promotic
WikipediaLinkedInYoutubeTwitterFacebook

Příklad na přenos souborů pomocí FTP (ActiveX)

Je to příklad na přenos souborů přes intranet/internet protokolem FTP. Předpokládá použití ActiveX objektu ChilkatFTP. Ten lze ve "free" verzi stáhnout ze stránek výrobce: http://www.chilkatsoft.com/downloads.asp. Výrobce rovněž nabízí příklady pro použití na stránkách http://www.example-code.com/vbscript/ftp.asp a dokumantaci k rozhraní objektu zveřejnil na stránce http://www.chilkatsoft.com/refdoc/xChilkatFtpRef.html.
 
Použitá technologie se spouští v synchroním režimu, proto bude vhodné v systému PROMOTIC k navázání spojení a přenosu souborů použít objekt PmSequencer. Ve skriptu je vytvořena instance na tento objekt pomocí metody CreateObject.
 
Skript pro odeslání souboru na FTP server v režimu pasivního přenosu.:
VBScriptVyber a zkopíruj do schránky

Dim oftp, success, localFilename, remoteFilename

Set oftp = CreateObject("ChilkatFTP.ChilkatFTP.1")
oftp.Hostname = "nameserver"
oftp.Username = "*****"
oftp.Password = "*****"

'Výchozí datový přenos je nastaven v "Active" módu (opakem je "Passive")
'Změna na pasivní režim přenosu se nastaví:
oftp.Passive = 1

'Připojení a přihlášení na FTP server.
success = oftp.Connect()
If success <> 1 Then
  Pm.MessageBox "Warning - Connect", oftp.LastErrorText, &H0
Else
  'Změna nebo nastavení složky na FTP serveru kde je nebo bude umístěn požadovaný soubor.
  success = oftp.ChangeRemoteDir("/FTP")
  If success <> 1 Then
    Pm.MessageBox "Warning - ChangeRemoteDir", oftp.LastErrorText, &H0
  Else
    'Přenesení souboru
    localFilename = "c:\uplist.txt"
    remoteFilename = "uplist.txt"

    success = oftp.PutFile(localFilename, remoteFilename)
    If success <> 1 Then
      Pm.MessageBox "Warning - PutFile", oftp.LastErrorText, &H0
    Else
      oftp.Disconnect
      Pm.MessageBox "Transfer file", "Soubor přenesen!", &H0
    End If
  End If
End If
 
Skript pro stažení souboru z FTP serveru v režimu pasivního přenosu.:
VBScriptVyber a zkopíruj do schránky

Dim oftp, success, localFilename, remoteFilename

Set oftp = CreateObject("ChilkatFTP.ChilkatFTP.1")
oftp.Hostname = "nameserver"
oftp.Username = "*****"
oftp.Password = "*****"

'Výchozí datový přenos je nastaven v "Active" módu (opakem je "Passive")
'Změna na pasivní režim přenosu se nastaví:
oftp.Passive = 1

'Připojení a přihlášení na FTP server.
success = oftp.Connect()
If success <> 1 Then
  Pm.MessageBox "Warning - Connect", oftp.LastErrorText, &H0
Else
  'Změna nebo nastavení složky na FTP serveru kde je nebo bude umístěn požadovaný soubor.
  'Tento krok pouze tehdy, pokud stahovaný soubor není v kořenovém adresáři pro FTP připojení
  success = oftp.ChangeRemoteDir("/FTP")
  If success <> 1 Then
    Pm.MessageBox "Warning - ChangeRemoteDir", oftp.LastErrorText, &H0
  Else
    'Stažení souboru
    localFilename = "c:\uplist.txt"
    remoteFilename = "uplist.txt"

    success = oftp.GetFile(remoteFilename, localFilename)
    If success <> 1 Then
      Pm.MessageBox "Warning - GetFile", oftp.LastErrorText, &H0
    Else
      oftp.Disconnect
      Pm.MessageBox "Transfer file", "Soubor stažen!", &H0
    End If
  End If
End If
© MICROSYS, spol. s r. o.Tavičská 845/21 703 00 Ostrava-Vítkovice