Promotic
WikipediaLinkedInYoutubeTwitterFacebook

Předkonfigurace Odesílání mailů z aplikace

Vytvoří objekt PmFolder s metodami a obrazem pro odesílání mailů z aplikace.
 
Tato předkonfigurace se vyvolá při zakládání nového objektu (např. volbou "Nový objekt" v lokálním menu objektu nebo stiskem klávesy Insert po označení objektu) a je zařazena ve skupině: " / Komunikace / Email".

Tuto předkonfiguraci je možné založit nad objektem: PmFolder nebo PmRoot.

 
- Předkonfigurace vytvoří objekt typu PmFolder, který má metodu SendEmail s parametry sTo, sSubject, sBody. V jejím úvodu jsou proměnné, které nastaví připojení na SMTP server a na konci je volána metoda SendEmailCDO, která zprávu odešle.
- Součástí předkonfigurace je také obraz pro zasílání zpráv ale ke komunikaci nutný není. Obsahuje grafické prvky určené pro zadání mailové adresy příjemce, předmětu odesílané zprávy a zadání obsahu těla zprávy. A prvek PmiButton, který v události onButtonUp volá metodu SendEmail s příslušnými parametry..
- V okně vyvolaném před vznikem objektu je nutné zadat údaje nezbytné pro konfiguraci SMTP serveru a identifikaci odesílatele mailových zpráv.
- Předkonfigurace obrazu (objektu PmPanel) je vytvořena tak, že je funkční i jako WEB obraz. Aby byla předkonfigurace funkční i na WEBu, je nutno objekt typu PmPanel povolit pro WEB (v záložce Web Server).
 
Metodu obrazu SendEmail lze vyvolat kdekoliv z aplikace.
Konfigurátory které lze nastavit před vytvořením předkonfigurace:
Název vytvářeného objektuNázev nově vytvořeného objektu ve stromu objektů aplikace. Je to systémový název a nesmí obsahovat prázdný řetězec, diakritiku, mezery a jako první znak nesmí být čislo.

Přednastaveno: "SendEmail"

Adresa SMTP serveru
Vaše uživatelská identifikace na SMTP serveru
Vaše heslo na SMTP serveru
Jméno odesílatele
Mailová adresa odesílatele
Skript pro odeslání emailu:
Dim nSendUsing, oMsg, oFlds, nSmtpAuthenticate, sSmtpServer
Dim sUserName, sPassword, nSmtpServerPort, bSmtpUseSsl, nSmtpConnectionTimeout
  
nSendUsing = 2 '1 = Odesílání zprávy pomocí lokálního servisního SMTP přenosu, 2 = Odesílání zprávy přes síť
sSmtpServer = "smtp.aol.com" 'Název nebo IP adresa na připojovaný SMTP server
nSmtpAuthenticate = 1 'Typ autentizace, Žádná=0, Basic=1 (Base64 encoded), NTLM=2
sUserName ="My Name" & "<you@aol.com>" 'Vaše uživatelská identifikace na SMTP serveru
sPassword = "******" 'Vaše heslo na SMTP serveru
nSmtpServerPort = 25 'Port serveru (obvykle 25)
bSmtpUseSsl = false 'Použít SSL při spojení (false nebo true)
nSmtpConnectionTimeout = 60 'Prodleva při spojení
  
Set oMsg = CreateObject("CDO.Message")
oMsg.BodyPart.Charset = "utf-8" ' "windows-1252" or "iso-8859-2" / ...
oMsg.Subject = "Test email from Promotic"
oMsg.From = "Name" & "<my@aol.com>"
oMsg.To = "xxxx@yahoo.com"
oMsg.TextBody = "Test email from Promotic.." & vbCrLf & "It was sent using SMTP authentication."
'oMsg.HTMLBody = "<h1>Test email from Promotic..</h1><p>It was sent using SMTP authentication.</p>"
oMsg.Addattachment "c:\temp\Text.txt"
  
'==Toto je sekce kde se definuje a konfiguruje připojení na vzdálený SMTP server==
Set oFlds = oMsg.Configuration.Fields
oFlds.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = nSendUsing
oFlds.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = sSmtpServer
oFlds.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = nSmtpAuthenticate
oFlds.Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = sUserName
oFlds.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = sPassword
oFlds.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = nSmtpServerPort
oFlds.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = bSmtpUseSsl
oFlds.Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = nSmtpConnectionTimeout
oFlds.Update
'==Konec sekce vzdálené konfigurace SMTP serveru==
  
oMsg.Send
 
www.w3schools.com/asp/asp_send_email.asp, msdn2.microsoft.com/en-us/library/ms526694.aspx
© MICROSYS, spol. s r. o.Tavičská 845/21 703 00 Ostrava-Vítkovice